Error 75 al abrir varios text files

[Alexand3r]

Buenas compañer@s.

Hace unos días abrí un post porque no conseguia abrir varios text files con un commondialog.

Aunque tengo un problema parecido, como en el anterior post se me quedó el problema más o menos resuelto, por eso he decido abrir otro. Espero no estar metiendo la pata haciendolo.

A ver, el problema que tenia antes, era que queria abrir varios archivos txt, y lo conseguí con el siguiente código y la ayuda del compi pkj:

Código:

Private Sub Command1_Click()

CommonDialog1.DialogTitle = "Seleccione un archivo con extension ass"
CommonDialog1.Filter = "Archivos con extension .ass|*.ass"
CommonDialog1.ShowOpen

If CommonDialog1.FileName = "" Then
   Exit Sub
Else
  
  Open CommonDialog1.FileName For Input As #1
  
  Text2 = Text2 & CommonDialog1.FileTitle & vbNewLine
  
  Line Input #1, Linea
    
  Text1.Text = Text1.Text & Linea & vbNewLine
  
  Close
  
End If

End Sub

Con ese código, puedo ir seleccionando varios archivos, y se van cargando en el Text1, solo la primera linea que contiene el text file, y en el Text2, solo el nombre del archivo.

Despues de tirarme tres o cuatro días buscando la posibilidad de seleccionar los distintos text files a la vez, encontre una linea de codigo que me permite hacerlo:

Código:

CommonDialog1.flags = cdlOFNAllowMultiselect Or cdlOFNFileMustExist Or cdlOFNExplorer

Sin embargo, me da
Error '75' en tiempo de ejecucion
Error de acceso a ruta o archivo

Y cuando le doy a depurar, me dice que el error está en la linea:

Código:

Open CommonDialog1.FileName For Input As #1

No sé ya como solucionarlo, si algún alma caritativa quisiera echarme un cable le estay agradecido.

Un saludo.

Alex

[pkj]

El problema que tienes y por el cual no quise comentarte la posibilidad del multiselect es que de ese modo, el valor de FileName no contiene la ruta al fichero que marcas, solo el nombre y extensión. Si pej. seleccionas "C:\texto.txt", en FileName solo tienes "Texto.txt". La ruta la tienes que añadir al abrir el fichero. Como yo tuve problemas con eso dejé de intentar usar ese método. Cuando quiero seleccionar varios ficheros añado un DriveList, un DirList y un FileList del que selecciono los ficheros, pero para no complicarte te dí esa solución.

Suerte con ello.

[Alexand3r]

Gracias nuevamente pkj.

Seguire buscando, si encuentro la solución, la posteo aquí.

Un saludo.

Miguel.

[pkj]

Ya que tanto empeño tienes te he buscado la solucion y así tambien la tendré yo.

Código vb:

Dim sFile() As String
 
  With CD1
    .InitDir = "C:\Windows"                         '
    .FileName = vbNullString                        'Clear out previous filename(s)
    .Filter = "All Files (*.*)|*.*" 'Set the input mask
    .FilterIndex = 1                                'Set index of filter
    'Must have explorer flag with multiselect flag!!!
    .Flags = cdlOFNHideReadOnly Or cdlOFNPathMustExist Or cdlOFNAllowMultiselect Or cdlOFNExplorer
    .DialogTitle = "Import Files"                  'Set caption of CD
    .CancelError = True                             'Die if there are any errors
    .MaxFileSize = 30000                            'Just to make sure we have enough room
    On Error Resume Next
    .ShowOpen                'Open
    
    Select Case Err.Number
      Case cdlCancel
        'Cancel was selected
        Exit Sub
      Case Is <> 0
        'Some other error occurred
        Exit Sub
      Case 0
        'No error occured
         sFile = Split(.FileName, ChrW$(0))              'Take apart null delimited list returned from multiselect CD
     End Select
     On Error GoTo 0
  End With
  
  If UBound(sFile) > 0 Then
    Dim f As Integer
    For f = 1 To UBound(sFile)
      MsgBox sFile(0) & sFile(f)
    Next f
  Else
    MsgBox sFile(0)
  End If
 

No sé donde tuve yo el problema, ya que parece facil, pero el caso es que me cansé y lo dejé.

Saludos

[Alexand3r]

Buenas y gracias pkj.

Genial.

Veras... buscando yo también, y juntando código de aquí y de allá, he hecho este código:

Código:

Private Sub Command1_Click()

    Dim vFiles As Variant
    Dim lFile As Long
    
    CommonDialog1.FileName = ""
    CommonDialog1.Flags = cdlOFNAllowMultiselect Or cdlOFNExplorer Or cdlOFNHideReadOnly
    CommonDialog1.Filter = "All files (*.*)|*.*"
    CommonDialog1.ShowOpen
        
    vFiles = Split(CommonDialog1.FileName, Chr(0))
    
    If UBound(vFiles) = 0 Then
      List1.AddItem CommonDialog1.FileTitle
    Else
      For lFile = 1 To UBound(vFiles)
        List1.AddItem vFiles(lFile)
      Next lFile
    End If
    
Dim cosa As String
Dim linea As String
Dim z As Integer

For z = 0 To Form1.List1.ListCount - 1
cosa = Form1.List1.List(z)

If cosa <> "" Then
       Open cosa For Input As #1
        Line Input #1, linea
            Text1.Text = Text1.Text & linea & vbNewLine
        Close #1
End If

Next

End Sub

Bueno, el código hace más o menos lo que quiero (me permite seleccionar varios archivos; me muestra en un listbox "solo" el nombre del fichero, sin la ruta; y en un textbox me muestra el contenido de la primera linea del text file), el problema, es que cuando despues de haber seleccionado x archivos (puede ser uno o varios), si vuelvo a abrir el CommonDialog para añadir algún otro, se repite lo que ya habia en el textbox, creo que el error debe de ser muy tonto, pero no consigo dar con la tecla para que no se repita, creo saber por que linea debe estar el fallo, pero creo que estoy hocicao y no consigo verlo desde fuera.

Si quieres, echale un vistazo a ver si consiguiéramos ver donde esta el fallo.

Si lo encontrase, lo vuelvo a postear.

Espero que también este te pueda servir de algo para cualquier cosa.

Un saludo, y agradezco mucho lo que me estas ayudando.

[erbuson]

Hola:

Ten en cuenta que el TextBox y el List tienen ya los datos de la primera búsqueda por lo que como precaución, antes de poner nada debes inicializar su contenido.

Yo pondría al entrar en la rutina y antes del Show
Text1.Text = ""
List1.Clear

Saludos

[pkj]

Como comenta erbuson, el fallo está en que no inicializas el ListBox.
Eso lo puedes hacer nada más entrar a la sub.
El TextBox lo puedes limpiar en un boton "Nuevo" o preguntando antes de empezar a cargar los textos seleccionados:

List1.Clear

....
...
commondialog1.showopen

If List1.ListCount > 0 Then
If MsgBox("¿Quieres agregar los textos a continuación del existente?",vbYesNo) = vbNo Then Text1.Text = ""

....
cargas los textos
...

End If

Que se dé bien.